本文主要是介绍Elixir学习笔记——可枚举和流，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！
虽然 Elixir 允许我们编写递归代码，但我们对集合执行的大多数操作都是在 Enum 和 Stream 模块的帮助下完成的。让我们学习如何操作。
Elixir 提供了可枚举的概念以及与之配合使用的 Enum 模块。我们已经学习了两种可枚举：列表和映射。
iex> Enum.map([1, 2, 3], fn x -> x * 2 end)
[2, 4, 6]
iex> Enum.map(%{1 => 2, 3 => 4}, fn {k, v} -> k * v end)
[2, 12]
Enum 模块提供了大量函数来转换、排序、分组、过滤和检索可枚举中的项目。它是开发人员在 Elixir 代码中经常使用的模块之一。有关 Enum 模块中所有函数的一般概述，请参阅 Enum 备忘单。
Elixir 还提供了范围（参见 Range），它们也是可枚举的：
iex> Enum.map(1..3, fn x -> x * 2 end)
[2, 4, 6]
iex> Enum.reduce(1..3, 0, &+/2)
6
正如名称所示，Enum 模块中的函数仅限于枚举数据结构中的值。对于特定操作（如插入和更新特定元素），您可能需要使用特定于数据类型的模块。例如，如果您想在列表中的给定位置插入元素，则应使用 List.insert_at/3 函数，因为将值插入范围等毫无意义。
我们说 Enum 模块中的函数是多态的，因为它们可以处理多种数据类型。特别是，Enum 模块中的函数可以处理实现 Enumerable 协议的任何数据类型。我们将在后面的章节中讨论协议，现在我们将讨论一种称为流的特定类型的可枚举。
积极或者惰性(Eager vs Lazy)
Enum 模块中的所有函数都是 Eager 函数。许多函数都期望可枚举并返回一个列表：
iex> odd? = fn x -> rem(x, 2) != 0 end
#Function<6.80484245/1 in :erl_eval.expr/5>
iex> Enum.filter(1..3, odd?)
[1, 3]
这意味着在使用 Enum 执行多个操作时，每个操作都会生成一个中间列表，直到我们得到结果：
iex> 1..100_000 |> Enum.map(&(&1 * 3)) |> Enum.filter(odd?) |> Enum.sum()
7500000000
上面的示例有一个操作流水线。我们从一个范围开始，然后将范围中的每个元素乘以 3。第一个操作现在将创建并返回一个包含 100_000 个项目的列表。然后我们保留列表中的所有奇数元素，生成一个新列表，现在有 50_000 个项目，然后我们对所有条目求和。
管道运算符
上述代码片段中使用的 |> 符号是管道运算符：它从其左侧的表达式获取输出，并将其作为第一个参数传递给其右侧的函数调用。其目的是突出显示一系列函数正在转换的数据。要了解它如何使代码更简洁，请查看上述未使用 |> 运算符重写的示例：
iex> Enum.sum(Enum.filter(Enum.map(1..100_000, &(&1 * 3)), odd?))
7500000000
流式编程(Streams)
作为 Enum 的替代方案，Elixir 提供了支持惰性操作的 Stream 模块：
iex> 1..100_000 |> Stream.map(&(&1 * 3)) |> Stream.filter(odd?) |> Enum.sum()
7500000000
Streams 是惰性的、可组合的枚举。
在上面的例子中，1..100_000 |> Stream.map(&(&1 * 3)) 返回一个数据类型，即一个实际的流，它表示范围 1..100_000 上的映射计算：
iex> 1..100_000 |> Stream.map(&(&1 * 3))
#Stream<[enum: 1..100000, funs: [#Function<34.16982430/1 in Stream.map/2>]]>
此外，它们是可组合的，因为我们可以管道传输许多流操作：
iex> 1..100_000 |> Stream.map(&(&1 * 3)) |> Stream.filter(odd?)
#Stream<[enum: 1..100000, funs: [...]]>
流不会生成中间列表，而是构建一系列计算，只有当我们将底层流传递给Enum 模块。处理大型（可能无限）集合时，流非常有用。
Stream 模块中的许多函数接受任何可枚举项作为参数并返回流作为结果。它还提供用于创建流的函数。例如，Stream.cycle/1 可用于创建无限循环给定可枚举项的流。请注意不要在这样的流上调用像 Enum.map/2 这样的函数，因为它们会永远循环：
iex> stream = Stream.cycle([1, 2, 3])
#Function<15.16982430/2 in Stream.unfold/2>
iex> Enum.take(stream, 10)
[1, 2, 3, 1, 2, 3, 1, 2, 3, 1]
另一方面，Stream.unfold/2 可用于从给定的初始值生成值：
iex> stream = Stream.unfold("hełło", &String.next_codepoint/1)
#Function<39.75994740/2 in Stream.unfold/2>
iex> Enum.take(stream, 3)
["h", "e", "ł"]
另一个有趣的函数是 Stream.resource/3，它可用于包装资源，保证它们在枚举之前打开并在之后关闭，即使在发生故障的情况下也是如此。例如，File.stream!/1 建立在 Stream.resource/3 之上以流式传输文件：
iex> stream = File.stream!("path/to/file")
%File.Stream{
line_or_bytes: :line,
modes: [:raw, :read_ahead, :binary],
path: "path/to/file",
raw: true
}
iex> Enum.take(stream, 10)
上面的示例将获取您选择的文件的前 10 行。这意味着流对于处理大文件甚至网络资源等慢速资源非常有用。
Enum 和 Stream 模块提供了广泛的功能，但您不必记住所有这些功能。熟悉 Enum.map/2、Enum.reduce/3 和其他名称中带有 map 或 reduce 的函数，您自然会对最重要的用例产生直觉。您也可以先关注 Enum 模块，然后仅在需要惰性的特定场景下才转到 Stream，以处理缓慢的资源或大型（可能无限）的集合。
接下来，我们将介绍 Elixir 的核心功能 Processes，它使我们能够以简单易懂的方式编写并发、并行和分布式程序。
这篇关于Elixir学习笔记——可枚举和流的文章就介绍到这儿，希望我们推荐的文章对编程师们有所帮助！
